1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

CHIP ALU {
    IN  
        x[16], y[16],  // 16-bit inputs        
        zx, // zero the x input?
        nx, // negate the x input?
        zy, // zero the y input?
        ny, // negate the y input?
        f,  // compute out = x + y (if 1) or x & y (if 0)
        no; // negate the out output?

    OUT 
        out[16], // 16-bit output
        zr, // 1 if (out == 0), 0 otherwise
        ng; // 1 if (out < 0),  0 otherwise

    PARTS:
	//zero x
	Mux16(a=x, sel=zx, out=x1);
	
	//negate x
	Not16(in=x1, out=xNegated);
	Mux16(a=x1, b=xNegated, sel=nx, out=x2);
	
	//zero y
	Mux16(a=y, sel=zy, out=y1);
	
	//negate y
	Not16(in=y1, out=yNegated);
	Mux16(a=y1, b=yNegated, sel=ny, out=y2);
	
	//f function
	Add16(a=x2, b=y2, out=added);
	And16(a=x2, b=y2, out=anded);
	Mux16(a=anded, b=added, sel=f, out=fresult);
	
	//negate output
	Not16(in=fresult, out=fnegated);
	Mux16(a=fresult, b=fnegated, sel=no, out=out, out[15]=firstDigit, out[0..7]=finalRight, out[8..15]=finalLeft);
	
	//zr
	Or8Way(in=finalLeft, out=zrl);
    Or8Way(in=finalRight, out=zrr);
    Or(a=zrl, b=zrr, out=nzr);
    Not(in=nzr, out=zr);
	
	//ng
	And(a=firstDigit, b=true, out=ng);
	
}