1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

CHIP CPU {

    IN  inM[16],         // M value input  (M = contents of RAM[A])
        instruction[16], // Instruction for execution
        reset;           // Signals whether to re-start the current
                         // program (reset==1) or continue executing
                         // the current program (reset==0).

    OUT outM[16],        // M value output
        writeM,          // Write to M? 
        addressM[15],    // Address in data memory (of M)
        pc[15];          // address of next instruction

    PARTS:
	//Decoding instruction bit
	
	And(a=instruction[15], b=instruction[15], out=cInstruction);
	Not(in=cInstruction, out=aInstruction);
	
	//Configuring Register and Mux Loads
	
	Or(a=aInstruction, b=instruction[5], out=aLoad); //loads if a instruction or a destination
	And(a=cInstruction, b=instruction[4], out=dLoad); //loads if d instruction or d destination
	And(a=cInstruction, b=instruction[12], out=AorM); //only puts instruction if c instruction or using a register
	
	//Main components
	
    Mux16(a=aluOut, b=instruction, sel=aInstruction, out=instructionOut); //sel = alu out or instruction to A Register
	ARegister(in=instructionOut, load=aLoad, out=regAOut, out[0..14]=addressM); //sel = d1 = store A or no
	Mux16(a=regAOut, b=inM, sel=AorM, out=AorMOut); //sel = a = outputting A or M
	DRegister(in=aluOut, load=dLoad, out=regDOut); //load = d2 = store D or no
	ALU(x=regDOut, y=AorMOut, zx=instruction[11], nx=instruction[10],
		zy=instruction[9], ny=instruction[8], f=instruction[7], no=instruction[6],
		out=outM, out=aluOut, zr=zrOut, ng=ngOut); //zx → no = c1 → c6 
	
	//Checking for PC jump
	
	Or(a=zrOut, b=ngOut, out=zrOrNeg); //checks whether number is positive
	Not(in=zrOrNeg, out=pos); //creates pos flag
	Not(in=zrOut, out=notZr);
	
	And(a=instruction[2], b=ngOut, out=jlt); //jump check for negative condition
	
	And(a=instruction[1], b=zrOut, out=jeq); //jump check for zero condition
	
	And(a=instruction[0], b=pos, out=jgtTemp); //jump check for pos condition
	And(a=jgtTemp, b=notZr, out=jgt);
	
	Or(a=jlt, b=jeq, out=jumpTemp);
	Or(a=jumpTemp, b=jgt, out=jumpToA); //checks to see if a jump is valid for any
	And(a=cInstruction, b=jumpToA, out=loadPC); //only jumps if c instruction
	PC(in=regAOut, load=loadPC, inc=true, reset=reset, out[0..14]=pc);
	
	And(a=instruction[3], b=cInstruction, out=writeM); //sets d3 (storage of M) as writeM
}